Archivos de la categoría ‘–Programación–’

El vúmetro es un dispositivo indicador en equipos de audio para mostrar el nivel de señal en unidades de volumen, también es llamado “indicador del volumen”.

Consta de un instrumento de bobina móvil o galvanómetro con una balística (amortiguamiento) determinada, alimentado por medio de un rectificador de onda completa que se conecta a la línea de audio mediante una resistencia en serie. No necesita más fuente de energía para su funcionamiento que la señal de entrada. Esencialmente permite visualizar las variaciones de la tensión en la señal de audio, rectificándola y obteniendo el valor medio. Este se obtiene por la balística del instrumento usado, no por una integración capacitiva. Lo que exige que el galvanómetro de un vúmetro no sea fabricado igual que otros tipos de medidores eléctricos (como los amperímetros, voltímetros, etc.) para conformar el estándar SVI (Standard Volume Indicator).

El vúmetro no fue diseñado para medir explícitamente la tensión de la señal, sino para que los usuarios tuvieran una referencia u objetivo de 0 VU, identificado como el 100% o 0 decibelios, en telefonía y en la modulación de los transmisores de la época, por lo que no era muy importante que el dispositivo no fuera extremadamente lineal o preciso para bajos niveles. En efecto, la escala de -20 VU a +3 VU, con 0 VU al 70% de la escala, fue limitado por la tecnología de la época. La mitad superior de la escala solo cubre 6 dB, permitiendo ajustar con precisión solo los niveles alrededor de 0 VU.

Se ha reemplazado en muchos equipos el tradicional vúmetro de aguja por indicadores luminosos con LEDs. Además del nivel ponderado, algunos vúmetros digitales también muestran los picos o máximos. Como regla general, los niveles de grabación deben ser tales que no superen el área roja más allá de 0 VU, o solo en raras ocasiones. Si el volumen de grabación es demasiado alto, la calidad del sonido y respuesta en frecuencia es generalmente más pobre y los efectos de saturación y recorte pueden ser especialmente problemáticos para un sistema de grabación digital. Por el contrario si el nivel es demasiado bajo, los niveles de ruido serán altos en relación a la señal principal que se está grabando.

Actualmente, la mayoría de las computadoras utilizan pantallas LED o LCD para indicar el nivel de sonido, por otro lado, dan un aspecto colorido y dramático.
Este proyecto consta de 6 visualizaciones diferentes que muestran gráficamente la señal de audio estéreo que ingresa a través de dos entradas analógicas del PIC.
Tiene múltiples aplicaciones, ya que podría ser un indicador de nivel de audio, control de nivel de líquido, voltímetro o amperímetro en una fuente de alimentación, indicador de temperatura, medición de una señal de RF, etc.

Datasheet PIC16F877A

El diagrama esquemático del vúmetro estéreo se observa en la siguiente imagen:

(click para ampliar)

Lista de Componentes
1 Microcontrolador PIC16F877A
1 Display LCD 16×2 con controlador Hitachi HD44780 o compatible
1 Cristal de Cuarzo 20MHz
2 Capacitores Cerámicos 27pF 50V
2 Capacitores Electrolíticos 1uF 63V
2 Diodos Rectificadores 1N4001
1 Trimpot horizontal multivuelta 10K
1 Resistencia 10KΩ 0.25W
1 Resistencia 4K7Ω 0.25W
2 Resistencias 330KΩ 0.25W
1 Pulsador N.A. o Push-Button N.A.

El código fuente del firmware del microcontrolador está escrito en el lenguaje PICBasic. Puede ser compilado sin ningún inconveniente utilizando la última versión del compilador PICBasic Pro Trial Version 3.0.7.1 y cargar el firmware en el PIC16F877A utilizando el programador PICKit 3 v3.01.

#CONFIG
        __config _HS_OSC & _WDT_OFF & _CP_OFF & _BOREN_OFF & _LVP_OFF

#ENDCONFIG

' *******************************************************************************
DEFINE OSC 20     ' Oscillator 20 MHz
' *******************************************************************************
ADCON1 = 00000000      ' Set all PORTA and PORTE as analog
PAUSE 500              ' Time to initiation of the LCD
DEFINE LCD_DREG PORTB  ' LCD data PORT B ships
DEFINE LCD_DBIT 4      ' LCD uses less than 0 or greater Bit 4
DEFINE LCD_RSREG PORTB ' LCD RS in the PORTB
DEFINE LCD_RSBIT 0     ' LCD RS PORTB.0
DEFINE LCD_EREG PORTB  ' LCD E in the PORTB
DEFINE LCD_EBIT 1      ' LCD E PORTB.1
DEFINE LCD_BITS 4      ' LCD using 4 or 8 bits for data
DEFINE LCD_LINES 2     ' Number of lines lcd
' *******************************************************************************
DEFINE ADC_BITS 8      ' Result of 8 or 10-bit ADC
DEFINE ADC_CLOCK 3     ' Set clock
DEFINE ADC_SAMPLEUS 50 ' Set sampling time in microseconds
' *******************************************************************************
CHANNEL var BYTE             ' Variable name
LINE    VAR BYTE             ' Variable name
COUNTER VAR BYTE             ' Variable name
REST    VAR BYTE             ' Variable name
Mark1   VAR BIT              ' Variable name
Mark2  var BYTE              ' Variable name
pushbutton    Var PORTB.2    ' button in the PORTB.2
TRISA =  %11111111
TRISB =  %00000100
TRISC =  %00000000

' *******************************************************************************
LCDOUT 254,64,1,2,5,5,5,5,2,1                      ' position CGRAM 0
LCDOUT 254,72,24,4,26,2,2,26,4,24                  ' 1 position CGRAM
LCDOUT $FE,1                                       ' Clear screen
' *******************************************************************************
GRAF1 :
Mark2 = 1
LCDOUT 254,64 , 0, 16, 16 , 16, 16 , 16, 16 , 0 ' 0 position CGRAM
LCDOUT 254,72 , 0, 24, 24 , 24, 24, 24 , 24, 0  ' 1 position CGRAM
LCDOUT 254,80 , 0, 28, 28 , 28, 28, 28 , 28, 0  ' CGRAM Position 2
LCDOUT 254,88 , 0, 30, 30 , 30, 30, 30 , 30, 0  ' 3 position CGRAM
LCDOUT 254,96 , 0, 31, 31 , 31, 31, 31 , 31, 0  ' 4 position CGRAM
PAUSE 300
GOTO BAR
' *******************************************************************************
GRAF2 :
Mark2 = 2
LCDOUT 254,64 , 0, 24, 24 , 24, 24, 24 , 24, 0 ' 0 position CGRAM
LCDOUT 254,72 , 0, 24, 24 , 24, 24, 24 , 24, 0 ' 1 position CGRAM
LCDOUT 254,80 , 0, 27, 27 , 27, 27, 27 , 27, 0 ' CGRAM Position 2
LCDOUT 254,88 , 0, 27, 27 , 27, 27, 27 , 27, 0 ' 3 position CGRAM
LCDOUT 254,96 , 0, 27, 27 , 27, 27, 27 , 27, 0 ' 4 position CGRAM
PAUSE 300
GOTO BAR
' *******************************************************************************
GRAF3 :
Mark2 = 3
LCDOUT 254,64 , 0, 0 , 0, 16, 16 , 0, 0 , 0 ' 0 position CGRAM
LCDOUT 254,72 , 0, 0 , 0, 24, 24 , 0, 0 , 0 ' 1 position CGRAM
LCDOUT 254,80 , 0, 0 , 0, 28, 28 , 0, 0 , 0 ' 2 Position CGRAM 
LCDOUT 254,88 , 0, 0 , 0, 30, 30 , 0, 0 , 0 ' 3 position CGRAM
LCDOUT 254,96 , 0, 0 , 0, 31, 31 , 0, 0 , 0 ' 4 position CGRAM
PAUSE 300
GOTO BAR
' *******************************************************************************
GRAF4 :
Mark2 = 4
LCDOUT 254,64 , 0, 16, 16 , 16, 16 , 16, 16 , 0 ' 0 position CGRAM
LCDOUT 254,72 , 0, 16, 16 , 16, 16 , 16, 16 , 0 ' 1 position CGRAM
LCDOUT 254,80 , 0, 20, 20, 20 , 20, 20 , 20, 0  ' 2 Position CGRAM  
LCDOUT 254,88 , 0, 20, 20, 20 , 20, 20 , 20, 0  ' 3 position CGRAM
LCDOUT 254,96 , 0, 21, 21 , 21, 21, 21 , 21, 0  ' 4 position CGRAM
PAUSE 300
GOTO BAR
' *******************************************************************************
GRAF5 :
Mark2 = 5
LCDOUT 254,64 , 0, 0 , 0, 4 , 0, 0 , 0, 0    ' 0 position CGRAM
LCDOUT 254,72 , 0, 0 , 4, 14 , 4, 0 , 0, 0   ' 1 Position CGRAM
LCDOUT 254,80 , 0, 0 , 14, 14 , 14, 0, 0, 0  ' 2 Position CGRAM 
LCDOUT 254,88 , 0, 4 , 14, 31 , 14, 4, 0, 0  ' 3 position CGRAM
LCDOUT 254,96 , 0, 14, 31, 31, 31 , 14, 0, 0 ' 4 position CGRAM
PAUSE 300
GOTO BAR
' *******************************************************************************
GRAF6 :
Mark2 = 6
LCDOUT 254,64,0,14,31,31,31,14,0,0           ' 0 position CGRAM
LCDOUT 254,72,0,14,31,31,31,14,0,0           ' 1 position CGRAM
LCDOUT 254,80,0,14,31,31,31,14,0,0           ' 2 Position CGRAM
LCDOUT 254,88,0,14,31,31,31,14,0,0           ' 3 position CGRAM
LCDOUT 254,96,0,0,0,31,0,0,0,0               ' 4 position CGRAM
PAUSE 300
' *******************************************************************************
BAR :
IF Mark1 = 1 THEN                             ' If true
LINE = $2: ADCIN 7, CHANNEL: Mark1 = 0        ' 1st line LCD shows L channel
ELSE                                          ' If it is not
LINE = $c0: ADCIN 6, CHANNEL: Mark1 = 1       ' 2nd Line LCD shows R channel
ENDIF 'End of the comparison
' *******************************************************************************
REST = ( CHANNEL // 5 )    ' Operation subtracted from the division
LCDOUT $FE,LINE            ' Start writing in the LCD
FOR COUNTER = 1 TO(CHANNEL/5) 'Count forward
LCDOUT 4                   ' 4 position CGRAM Print
NEXT COUNTER               ' Returns to COUNTER
IF REST = 1 THEN  LCDOUT 0 ' Print CGRAM position 0
IF REST = 2 THEN  LCDOUT 1 ' Print CGRAM Position 1
IF REST = 3 THEN  LCDOUT 2 ' Prints 2 position CGRAM
IF REST = 4 THEN  LCDOUT 3 ' 3 position CGRAM Print
LCDOUT 20, 20 , 20         ' Clearing 3 characters
' *******************************************************************************
IF (pushbutton = 1) and (Mark2 = 6) THEN GRAF1   '1 ° Viewing 
IF (pushbutton = 1) and (Mark2 = 1) THEN GRAF2   '2 ° Viewing
IF (pushbutton = 1) and (Mark2 = 2) THEN GRAF3   '3 ° Viewing 
IF (pushbutton = 1) and (Mark2 = 3) THEN GRAF4   '4 ° Viewing 
IF (pushbutton = 1) and (Mark2 = 4) THEN GRAF5   '5 ° Viewing 
IF (pushbutton = 1) and (Mark2 = 5) THEN GRAF6   '6 ° Viewing 
' *******************************************************************************
GOTO BAR
END

PICBasic Pro Trial Version 3.0.7.1 [incluye MPASM v8.90, Microcode Studio 5 (MCSX) para PBP v3, PBP 3.0.7.1]
Tamaño: 123.1MB
SHA1 Hash: C449786CFE50B26EB6818F9C35E10C718C36F6AD
Descarga

PICKit 3 v3.01
Tamaño: 8.4MB
SHA1 Hash: 34600B01B759F65DF993E1FA6408B4B3B3BA4AC9
Descarga

Además también se encuentra disponible para descargar el firmware ya compilado, listo para cargar en el microcontrolador.

VuMeter v1.0 HEX
Tamaño: 2KB
SHA1 Hash: 9D1F393C4EA3B561377988757898DAE7
Descarga

Arduino es una plataforma prácticamente infinita para todo tipo de aplicaciones como lo hemos visto en este humilde blog de entre millones que existen en la web. En este espacio comenzamos con aplicaciones de Hacking, luego incursionamos en la fascinante disciplina de la Robótica y últimamente avanzamos sobre increíble universo de los Videojuegos.

Anteriormente publicamos juegos (basados en la librería VGAx desarrollada por Sandro Maffiodo) como, por ejemplo:

Y juegos más sencillos basados simplemente en LEDs y pulsadores como

En esta ocasión continuaremos con la construcción de juegos sencillos, pero algo más elaborados utilizando matrices de LEDs controladas por el circuito integrado MAX7219.
Pong (o Tele-Pong) fue un videojuego de la primera generación de videoconsolas publicado por Atari, creado por Nolan Bushnell y lanzado el 29 de noviembre de 1972. Pong está basado en el deporte de tenis de mesa (o ping pong). La palabra Pong es una marca registrada por Atari Interactive, mientras que la palabra genérica «pong» es usada para describir el género de videojuegos «bate y bola». La popularidad de Pong dio lugar a una demanda de infracción de patentes y ganada por parte de los fabricantes de Magnavox Odyssey, que poseía un juego similar.
Pong es un juego de deportes en dos dimensiones que simula un tenis de mesa. El jugador controla en el juego una paleta moviéndola verticalmente en la parte izquierda de la pantalla, y puede competir tanto contra un oponente controlado por computadora, como con otro jugador humano que controla una segunda paleta en la parte opuesta. Los jugadores pueden usar las paletas para pegarle a la pelota hacia un lado u otro. El objetivo consiste en que uno de los jugadores consiga más puntos que el oponente al finalizar el juego. Estos puntos se obtienen cuando el jugador adversario falla al devolver la pelota.

Este videojuego es un verdadero clásico y es sumamente adictivo para jugar durante breves intervalos de tiempo. Ya sea esperando un micro o taxi, alguna hora o minutos libres en la Universidad o Colegio, o simplemente de noche hasta que logramos conciliar el sueño.
Esta variante contiene tres niveles de dificultad aumentado la velocidad de desplazamiento de la pelota a medida que avanzamos de nivel. En el último nivel la pelota se desplaza muy rápidamente, no apto para cardíacos, y si logramos superar este nivel ocurre una secuencia que podrán observar en el gameplay que se encuentra al final de la publicación y solo apto para verdaderos fanáticos.

La Matriz de LEDs

Una matriz LEDs es un display formado por múltiples LEDs en distribución rectangular. Existen distintos tamaños, siendo el más habitual los cuadrados de 8×8 LEDs.
Podemos combinar varios módulos para formar un display mucho mayor. En estos display podemos mostrar textos, dibujos o animaciones, como desplazar un texto (scroll).
Por lo demás, son diodos LEDs totalmente normales, organizados en forma de matriz, que tendremos que multiplexar para poder iluminar uno u otro punto.
Si los diodos se unen por el positivo, se dice que son matrices de Ánodo común, y si se une por el negativo decimos que son de Cátodo común. Dependiendo del fabricante podemos encontrar de ambos tipos.

Encender una matriz de LEDs directamente con Arduino requiere emplear una gran cantidad de pines, lo cual supondría un gran desperdicio de recursos. Por este motivo, lo normal es siempre utilizar un controlador específicamente diseñado para esta función. Un controlador habitualmente empleado por ser barato y sencillo es el circuito integrado MAX7219.

Circuito Integrado MAX7219

Encender una matriz de 8×8 LED requeriría 16 señales digitales y un trabajo constante del procesador para refrescar la imagen. Eso es una cantidad enorme de recursos para cualquier autómata, que estaríamos desperdiciando para simplemente encender un display.
Por este motivo, utilizamos el circuito integrado MAX7219 que está especialmente diseñado para encender displays de 7 segmentos y matrices de LEDs, liberando al procesador para hacer tareas mucho más valiosas y productivas.
La comunicación con el circuito integrado MAX7219 se realiza mediante el bus SPI por lo que sólo se requieren 3 pines de Arduino (SS, MOSI y SCK). Además, ni siquiera “ocupamos” en su totalidad estos pines, ya que con el mismo bus podemos controlar múltiples dispositivos.
Por último, las placas MAX7219 generalmente incorporan un puerto de entrada y salida, de forma que podemos combinar múltiples controladores sin ninguna dificultad.
MAX7219 Datasheet

El diagrama esquemático de esta variante de Arduino Pong se observa en la siguiente imagen:

(click para ampliar)

Lista de Componentes
1 Resistencia 10KΩ 0.25W
1 Potenciómetro Lineal 10KΩ
1 Transistor NPN 2SC1815
2 Módulos con Matrices de LEDs 8×8 con Circuito Integrado MAX7219 c/u. Cátodo Común [Color Rojo en caso de aplicar Red Mod]
1 Buzzer Pasivo 5V
1 Placa Arduino Nanino
Librería LedControl desarrollada por wayoda

#include <LedControl.h>

#define DATA_PIN    12
#define CLOCK_PIN   11
#define CS_PIN      10
#define NUM_DEVICES 2
#define KNOB_PIN    A0
#define RANDOM_PIN  A1
#define SPEAKER_PIN 7

#define N_a   440
#define N_f   349
#define N_cH  523
#define N_eH  659
#define N_fH  698
#define N_gS  415

int step_col, step_row, subidas, OLD_X, sensor, row, col, sc, sr, dly;
int row_bar = 0;
int X = 4;
int cnt = 0;
int desarma = 0;

boolean showBars_enabled = false;

LedControl LC = LedControl(DATA_PIN, CLOCK_PIN, CS_PIN, NUM_DEVICES);

byte MSG[8 * 20];
byte SPACE[8] = {
    B00000000,
    B00000000,
    B00000000,
    B00000000,
    B00000000,
    B00000000,
    B00000000,
    B00000000
};
byte W[8] = {
    B00000000,
    B01000010,
    B01000010,
    B01000010,
    B01000010,
    B01011010,
    B01100110,
    B00000000
};
byte I[8] = {
    B00000000,
    B00111100,
    B00011000,
    B00011000,
    B00011000,
    B00011000,
    B00111100,
    B00000000
};
byte N[8] = {
    B00000000,
    B01000010,
    B01100010,
    B01010010,
    B01001010,
    B01000110,
    B01000010,
    B00000000
};
byte E[8] = {
    B00000000,
    B01111110,
    B01000000,
    B01111100,
    B01000000,
    B01000000,
    B01111110,
    B00000000
};
byte R[8] = {
    B00000000,
    B01111100,
    B01000010,
    B01111100,
    B01001000,
    B01000100,
    B01000010,
    B00000000
};

void loose()
{
    delay(80);

    for(row = 0; (row < 16); row++) {
        setROW(row, 0xFF);
        tone(SPEAKER_PIN, (row * 500), 10);
        delay(20);
    }

    delay(130);

    for(row = 15; (row >= 0); row--) {
        setROW(row, 0x00);
        tone(SPEAKER_PIN, (row * 500), 10);
        delay(20);
    }
}

void showBars(boolean show)
{
    showBars_enabled = show;

    if(show) {
        row_bar = (2 + random(5));
    }

    setROW(row_bar, (show == true ? 0xFF : 0x00));
}

void setLED(int l, int c, boolean state)
{
    int disp = 0;

    if(l > 7) {
        l = (l - 8);
        disp = 1;
    }

    LC.setLed(disp, l, c, state);
}

void setROW(int r, char ch)
{
    int disp = 0;

    if(r > 7) {
        r = (r - 8);
        disp = 1;
    }

    LC.setRow(disp, r, ch);
}

void copyLetter(byte *ch,int pos)
{
    int i;

    for(i = 0; (i < 8); i++) {
        *(MSG + i + (pos * 8)) = *( ch + i);
    }
}

void showMSG(int qtde, int tempo)
{
    int idx;

    LC.clearDisplay(0);
    LC.clearDisplay(1);

    for(idx = 0; (idx < (8 * qtde)); idx++) {
        for(row = 0; (row < 16); row++) {
            setROW(row, *(MSG + row + idx));
        }
		
        delay(tempo);
    }

    LC.clearDisplay(0);
    LC.clearDisplay(1);
}

void beep(int frequencyInHertz, long timeInMilliseconds)
{
    int x;
    long delayAmount = (long)(1000000 / frequencyInHertz);
    long loopTime = (long)((timeInMilliseconds * 1000) / (delayAmount * 2));

    for(row = 0; (row < 16); row++) {
        setROW(row,0xFF);
    }

    for (x = 0; (x < loopTime); x++) {
        digitalWrite(SPEAKER_PIN, HIGH);
        delayMicroseconds(delayAmount);
        digitalWrite(SPEAKER_PIN, LOW);
        delayMicroseconds(delayAmount);
    }

    LC.clearDisplay(0);
    LC.clearDisplay(1);

    delay(20);
}

void march()
{
    beep(N_a, 500);
    beep(N_a, 500);
    beep(N_a, 500);
    beep(N_f, 350);
    beep(N_cH, 150);

    beep(N_a, 500);
    beep(N_f, 350);
    beep(N_cH, 150);
    beep(N_a, 1000);

    beep(N_eH, 500);
    beep(N_eH, 500);
    beep(N_eH, 500);
    beep(N_fH, 350);
    beep(N_cH, 150);

    beep(N_gS, 500);
    beep(N_f, 350);
    beep(N_cH, 150);
    beep(N_a, 1000);
}

void winner()
{
    copyLetter(SPACE, 0);
    copyLetter(SPACE, 1);

    copyLetter(W, 2);
    copyLetter(I, 3);
    copyLetter(N, 4);
    copyLetter(N, 5);
    copyLetter(E, 6);
    copyLetter(R, 7);

    copyLetter(SPACE, 8);
    copyLetter(SPACE, 9);

    showMSG(9, 80);

    march();

    setup();
}

void setup() {
    pinMode(KNOB_PIN, INPUT);      // Potentiometer 10K Linear (GND, KNOB_PIN, +5v)
	pinMode(RANDOM_PIN, INPUT);    // Random Seed
    pinMode(SPEAKER_PIN, OUTPUT);  // Passive Buzzer

    LC.shutdown(0, false);
    LC.setIntensity(0, 8);
    LC.clearDisplay(0);

    LC.shutdown(1, false);
    LC.setIntensity(1, 8);
    LC.clearDisplay(1);

    randomSeed(analogRead(RANDOM_PIN) * millis());

    loose();

    dly = 500;

    setLED(15, X, true);
    setLED(15, (X + 1), true);
    setLED(15, (X + 2) ,true);
    OLD_X = (-1);
    subidas = 0;

    step_col = 1;
    step_row = 1;

    sc = step_col;
    sr = step_row;

    row = ((-1) + random(3));
    col = random(8);

    showBars(false);
}

void loop()
{
    sensor = analogRead(KNOB_PIN);

    X = map(sensor, 0, 980, 1, 6);

    if(X != OLD_X) {
        OLD_X = X;
        setROW(15, 0x00);
        setLED(15, (X - 1),true);
        setLED(15, X, true);
        setLED(15, (X + 1), true);
    }

    if(cnt == 0) {
        setLED(row, col, false);

        if((subidas == 1 || random(2) == 1) && showBars_enabled == false && row == 0) {
            showBars(true);
            subidas = 0;
            desarma = (2 + random(5));
        }

        if((subidas == desarma) && (showBars_enabled == true)) {
            showBars(false);
            subidas = 0;
        }

        if(col == 7) {
            sc = -step_col;
            tone(SPEAKER_PIN, 1000, 20);
        }

        if(col == 0) {
            sc = step_col;
            tone(SPEAKER_PIN, 1000, 20);
        }

        if(row == 0) {
            sr = step_row;
            subidas++;
            dly -= 5;
            tone(SPEAKER_PIN, 1000, 20);
        }

        if(dly <= 190) {
            winner();
        }

        if(showBars_enabled == true && sr > 0 && row < row_bar) {
            if(row == (row_bar - 1)) {
                sr = -step_row;
                tone(SPEAKER_PIN, 1000, 20);
            }
        }

        if(row == 14)
        {
            if(col >= (X - 1) && col <= (X + 1)) {
                sr = -step_row;
				tone(SPEAKER_PIN, 1500, 20);
			}
            else if(col == (X - 2) && (sc > 0)) {
                sr = -step_row;
                sc = -step_col;
                tone(SPEAKER_PIN, 1500, 20);
            }
            else if(col == (X + 2) && (sc < 0)) {
                sr = -step_row;
                sc = step_col;
                tone(SPEAKER_PIN, 1500, 20);
            }
        }

        row += sr;
        col += sc;

        if(col == 8) {
            col = 7;
        }

        if(col == (-1)) {
            col = 0;
        }

        setLED(row, col, true);

        if(row == 15) {
            setup();
        }
    }

    cnt++;

    if(cnt == dly) {
        cnt = 0;
    }
}

(click para ampliar)

(click para ampliar)

(click para ampliar)

(click para ampliar)

(click para ampliar)

(click para ampliar)

(click para ampliar)

(click para ampliar)

(click para ampliar)

(click para ampliar)

(click para ampliar)

Red Mod
La cinta Kapton es resistente al calor y eléctricamente aislante que se usa mucho en electrónica e impresión 3D. Si has estado en esta afición por un tiempo hay una buena probabilidad de que tengas un rollo a mano.

Una o dos capas de cinta Kapton aplicada a las matrices las hacen menos propensas a lavarse bajo luz brillante. El color de la cinta es lo suficientemente similar a los LEDs rojos que brillan a través con poca dificultad, mientras que la mayoría de la luz ambiente está bloqueada.

La película de enmascarar “Rubylith” (empleada en diseño gráfico) probablemente funcionaría igual de bien, o quizás mejor. Este film puede conseguirse en tiendas de arte decentes de la vieja escuela.

En publicaciones anteriores hemos visto diferentes mecanismos de control para nuestro robot, tanto manuales (Construyendo Nuestro Propio Robot Desde Cero – Parte 3) como autónomos (Arduino Robot Seguidor de Líneas y Laberintos). Ahora veremos una alternativa más, también inalámbrica, al igual que en la publicación anterior (Arduino Robot Controlado por Bluetooth y Android App) y que en estos últimos años ha crecido de manera exponencial en el mercado. El lector perspicaz ya advirtió que se trata de la tecnología Wi-Fi (Wireless Fidelity), omnipresente en el mercado y en nuestros hogares.

En cuanto empieces a buscar algo de Wi-Fi económico, te encontrarás con el módulo Wi-Fi ESP8266, fabricado por ESPRESSIF Systems, el cual es muy parecido a los módulos Bluetooth de la publicación anterior, y que al igual que ellos incluye toda la electrónica necesaria para la comunicación RF en la banda Wi-Fi, así como la pila TCP/IP y se comunica con nosotros a través de un puerto serie.

De hecho, exactamente al igual que los módulos Bluetooth HC-06 y HC-05, se gobierna mediante comandos AT, algo que ya no tiene secretos para los seguidores de este blog, y todo por un precio similar al de los módulos Bluetooth.
Lo primero, es decir que es un módulo muy sencillo y diseñado desde el principio con la “Internet of Things” en mente (IoT), y por eso incluye todo lo necesario para conectarse a un punto de acceso Wi-Fi o actuar por sí mismo como punto de acceso Wi-Fi mediante comandos AT, vía un puerto serie, que puede ser configurado a diferentes velocidades.

Este circuito integrado es una pequeña maravilla tecnológica. Está diseñado y pensado para ser la solución ideal para todo el que necesite un “Todo en uno Wi-Fi” para proyectos de hobby, IoT o producto comercial sin complicaciones. Y lo más importante, lo consigue.

  • Voltaje de alimentación: 3.3V
  • Procesador interno de 32 bits a 80 MHz (se puede incrementar hasta 160MHz).
  • 80KB de DRAM.
  • 35KB de IRAM, memoria rápida para el procesador.
  • 512KB (hasta 1MB, dependiendo de la versión del módulo) de memoria flash para nuestros programas.
  • Pila TCP/IP Wi-Fi a 2.4 GHz (b/g/n).
  • 30 metros de alcance teórico.

Nota del Autor: de hecho, el módulo ESP8266 incluye un pequeño procesador interno que podríamos programar para funcionar de modo autónomo y dispone de un par de puertos GPIO (General Purpose Input Output) para su uso como activadores. Es posible programarlo desde el IDE Arduino, y más interesante aún, con MicroPython.

Lista de Componentes
1 Plataforma Turtle2WD con placa Arduino UNO R3 y Shield de Control de Motores ensamblados anteriormente.
1 Adaptador Sparkfun FTDI USB – UART TTL 3.3V
1 Módulo Wi-Fi ESP8266 (ESP-01)
1 Convertidor Bidireccional de Niveles Lógicos Sparkfun.
1 Capacitor Electrolítico 1000uF 6.3V
2 Baterías AA 1.5V de Alto Rendimiento
1 Portapilas para 2 Baterías AA

Antes de instalar el módulo en nuestro robot, modificaremos algunos parámetros de su configuración mediante comandos AT. Para llevar a cabo esta tarea sólo necesitamos descargar el documento que contiene el set de instrucciones AT ESP8266 y un emulador de terminal RS232.

Set de Instrucciones AT ESP8266

Termite 3.3
Tamaño: 294KB
SHA1 Hash: 5A7DEBD9E1F245EB87FAEF397187752D5CFF1841
Descarga     Mirror

A continuación conectaremos nuestro módulo al Adaptador FTDI USB – UART TTL 3.3V como se muestra en la siguiente imagen:

(click para ampliar)

Ahora, el emulador de terminal (en nuestro caso, Termite) debe estar configurado de la siguiente manera, que son los parámetros por defecto de nuestro módulo Wi-Fi.

Habiendo logrado una conexión exitosa en el paso anterior, ahora debemos enviar los comandos AT necesarios para configurar nuestro módulo. En la siguiente imagen se observa la secuencia de comandos enviados:

AT
AT+CWSAP_DEF="TURTLE2WD","",1,0,4
AT+UART_DEF=19200,8,1,0,0

Nuestros comandos enviados se encuentran en color azul, en color verde se encuentran las respuestas de nuestro módulo y el eco local de la consola. Con la ejecución exitosa de estos comandos modificamos el SSID de nuestro módulo por “TURTLE2WD” para identificarlo fácilmente y redujimos la velocidad del puerto serie a 19200bps lo cual nos permite utilizar cables de mayor longitud para el montaje en caso de ser necesario.

Habiendo finalizado exitosamente los pasos anteriores, compilaremos y cargaremos en nuestro Arduino Uno R3 el sketch correspondiente, cuyo código fuente se encuentra a continuación:

/*
Caracteristicas:
- Control por Wi-Fi utilizando el modulo ESP8266
- Interfaz web con jquey para envio de peticiones GET
- Id de botones para envio de datos
W: Adelante
S: Atras
A: Izquierda
D: Derecha
L: Inicio/Parada Modo Vehiculo

Q: Incrementar Velocidad
T: Disminuir Velocidad
X: Encendido/Apagado Luz Frontal

- Detencion automatica en caso de detectar bordes.
*/

#define     PWM_RIGHT   3     // (Control Velocidad Motor Derecho) Timer2 8 bits D3
#define     PWM_LEFT    11    // (Control Velocidad Motor Izquierdo) Timer2 8 bits D11
#define     DIR_A       12    // (Control de Direccion de Motores) D12
#define     DIR_B       13    // (Control de Direccion de Motores) D13
#define     MAX_SPEED   200   // Velocidad Maxima
#define     MIN_SPEED   100   // Velocidad Minima
// -----

// Iluminacion
#define     LED_LIGHT   7
// -----

// Sensores Reflectivos Detectores de Bordes
#define     BORDER_L    A2    // Sensor Izquierdo Externo
#define     BORDER_R    A5    // Sensor Derecho Externo

// Serial commands
#define     DIR_FORWARD     'W'
#define     DIR_BACKWARD    'S'
#define     DIR_LEFT        'A'
#define     DIR_RIGHT       'D'
#define     START_STOP_V    'L'
#define     INC_SPEED       'Q'
#define     DEC_SPEED       'T'
#define     FRONT_LIGHT     'X'
// -----

#define     DEBUG   false

boolean stopped;

byte speed, connectionid;

char data;

void forward() {
    digitalWrite(DIR_A, LOW);
    digitalWrite(DIR_B, LOW);
}

void backward() {
    digitalWrite(DIR_A, HIGH);
    digitalWrite(DIR_B, HIGH);
}

void rotateleft() {
    digitalWrite(DIR_A, LOW);
    digitalWrite(DIR_B, HIGH);
}

void rotateright() {
    digitalWrite(DIR_A, HIGH);
    digitalWrite(DIR_B, LOW);
}

void stop() {
    analogWrite(PWM_LEFT, 0);
    analogWrite(PWM_RIGHT, 0);
}

void setspeed(boolean sp) {
    if (sp) {
        if (speed < MAX_SPEED) {
            speed += 50;
            analogWrite(PWM_LEFT, speed);
            analogWrite(PWM_RIGHT, speed);
        }
    }
    else
    {
        if (speed > MIN_SPEED) {
            speed -= 50;
            analogWrite(PWM_LEFT, speed);
            analogWrite(PWM_RIGHT, speed);
        }
    }
}

void setlight() {
    digitalWrite(LED_LIGHT, !(digitalRead(LED_LIGHT)));
}

boolean isborder() {
    if ((digitalRead(BORDER_L) == HIGH) || (digitalRead(BORDER_R) == HIGH))
        return true;
    else
        return false;
}

String sendData(String command, const word timeout, boolean debug) {
    String response = "";

    Serial.print(command); // send the read character to the esp8266

    unsigned long time = millis();

    while ((time + timeout) > millis()) {
        while(Serial.available()) {
            // The esp has data so display its output to the serial window
            char c = Serial.read(); // read the next character.
            response += c;
        }
    }

    if (debug)
        Serial.print(response);

    return response;
}

void setup() {
    pinMode(PWM_LEFT, OUTPUT);
    pinMode(PWM_RIGHT, OUTPUT);
    pinMode(DIR_A, OUTPUT);
    pinMode(DIR_B, OUTPUT);
    pinMode(LED_LIGHT, OUTPUT);

    pinMode(BORDER_L, INPUT);
    pinMode(BORDER_R, INPUT);

    digitalWrite(LED_LIGHT, LOW);

    stopped = true;

    speed = MIN_SPEED;

    Serial.begin(19200);

    sendData("AT+CIPMUX=1\r\n", 1000, DEBUG); // configure for multiple connections
    sendData("AT+CIPSERVER=1,80\r\n", 1000, DEBUG); // turn on server on port 80
}

void loop() {
    if (Serial.available()) {
        if (Serial.find("+IPD,")) {
            delay(100);
            connectionid = (Serial.read() - 48);

            Serial.find("cmd=");
            data = Serial.read();

            if (data == START_STOP_V) {
                if (stopped) {
                    forward();

                    analogWrite(PWM_LEFT, speed);
                    analogWrite(PWM_RIGHT, speed);

                    stopped = false;
                }
                else
                {
                    stop();
                    stopped = true;
                }
            }

            switch (data) {
                case DIR_FORWARD:
                    if (!stopped)
                        forward();
                    break;

                case DIR_BACKWARD:
                    if (!stopped)
                        backward();
                    break;

                case DIR_LEFT:
                    if (!stopped)
                        rotateleft();
                    break;

                case DIR_RIGHT:
                    if (!stopped)
                        rotateright();
                    break;

                case INC_SPEED:
                    if (!stopped)
                        setspeed(true);
                    break;

                case DEC_SPEED:
                    if (!stopped)
                        setspeed(false);
                    break;

                case FRONT_LIGHT:
                    setlight();
                    break;

                default:
                    break;
            }

            String closecommand = "AT+CIPCLOSE=" + String(connectionid) + "\r\n";
            sendData(closecommand, 100, DEBUG);
        }
    }

    if (isborder())
        stop();
}

En este punto nos encontramos en la etapa final. A continuación conectaremos nuestro módulo Wi-Fi a la placa Arduino UNO R3, como se observa en la siguiente imagen:

(click para ampliar)

Por último necesitamos la interfaz web desde la cual controlaremos nuestro robot. Consta de un documento HTML y jQuery, una biblioteca multiplataforma de JavaScript, que permite simplificar la manera de interactuar con los documentos HTML, manipular el árbol DOM, manejar eventos, desarrollar animaciones y agregar interacción con la técnica AJAX a páginas web. jQuery es la biblioteca de JavaScript más utilizada.

Interfaz Web
Tamaño: 27.5KB
SHA1 Hash: 0C9AE81B92C8243C362C2DFA94C79065D8D3447E
Descarga


En publicaciones anteriores hemos visto diferentes mecanismos de control para nuestro robot, tanto manuales (Construyendo Nuestro Propio Robot Desde Cero – Parte 3) como autónomos (Arduino Robot Seguidor de Líneas y Laberintos). Ahora veremos una alternativa más, también inalámbrica, mucho más eficiente que los rayos infrarrojos (IR) y muy popular entre los teléfonos móviles (sí, controlaremos nuestro robot a través de nuestro teléfono móvil/tablet). De entre todos los módulos de control inalámbricos existentes para Arduino, el Bluetooth es, en mi humilde opinión, el más interesante. Es un módulo de muy bajo costo, muy sencillo de conectar (solo posee dos pines omitiendo VCC y GND), funciona como un puerto serie estándar, es compatible con cualquier dispositivo existente el mercado actual, como laptops, tablets y teléfonos móviles, lo que le otorga una ventaja más a las mencionadas anteriormente: versatilidad.

Básicamente existen 3 tipos de módulos Bluetooth en el mercado actual:

  • HC-05: Maestro/Esclavo. Puede conectarse a otros módulos (Modo Maestro) o aceptar conexiones de otros módulos comportándose como puente inalámbrico serie (Modo Esclavo).
  • HC-06: Esclavo. Sólo puede aceptar conexiones de otros módulos, comportándose como puente inalámbrico serie (Modo Esclavo).
  • HC-07: Esclavo (de muy bajo costo, menor a HC-06 y escasa documentación. Set de comandos AT limitado).

Para controlar nuestro robot utilizaremos el último módulo de la lista, HC-07, ya que sólo necesitamos establecer una conexión desde nuestro teléfono móvil/tablet hacia nuestro robot para enviar los comandos necesarios.

Lista de Componentes
1 Plataforma Turtle2WD con placa Arduino UNO R3 y Shield de Control de Motores ensamblados anteriormente.
1 Módulo Bluetooth HC-07.
Teléfono móvil o Tablet con Sistema Operativo Android 2.3.3 o superior.
Aplicación “Arduino Bluetooth Controller” (disponible en Google Play Store).

La aplicación “Arduino Bluetooth Controller” nos ofrece diferentes modos para controlar nuestro robot, incluyendo una terminal para enviar y/o recibir datos mediante el enlace bluetooth. Para nuestro caso particular, utilizaremos los modos “Vehicle Mode” y “Controller Mode“. El primero nos permite controlar nuestro robot utilizando el giroscopio y acelerómetro de nuestro teléfono móvil/tablet y el segundo nos permite controlar nuestro robot mediante un joystick táctil.

En primer lugar, debemos descargar e instalar en nuestro teléfono móvil/tablet la aplicación mencionada anteriormente disponible en Google Play Store.
Habiendo finalizado exitosamente el paso anterior, compilaremos y cargaremos en nuestro Arduino Uno R3 el sketch correspondiente, cuyo código fuente se encuentra a continuación:

/*
Caracteristicas:
- Aplicacion "Arduino Bluetooth Controller" (FREE - Play Store)
- Manejo por enlace bluetooth mediante las teclas:
W: Adelante
S: Atras
A: Izquierda
D: Derecha
L: Inicio/Parada Modo Vehiculo
V: Inicio/Parada Modo Joystick

Q: Incrementar Velocidad
T: Disminuir Velocidad
x: Encendido/Apagado Luz Frontal

- Detencion automatica en caso de detectar bordes.
*/

#define     PWM_RIGHT   3     // (Control Velocidad Motor Derecho) Timer2 8 bits D3
#define     PWM_LEFT    11    // (Control Velocidad Motor Izquierdo) Timer2 8 bits D11
#define     DIR_A       12    // (Control de Direccion de Motores) D12
#define     DIR_B       13    // (Control de Direccion de Motores) D13
#define		MAX_SPEED	200   // Velocidad Maxima
#define		MIN_SPEED	100   // Velocidad Minima
// -----

// Iluminacion
#define     LED_LIGHT   7
// -----

// Sensores Reflectivos Detectores de Bordes
#define		BORDER_L	A2    // Sensor Izquierdo Externo
#define		BORDER_R	A5    // Sensor Derecho Externo

// Serial commands
#define     DIR_FORWARD		'W'
#define     DIR_BACKWARD	'S'
#define     DIR_LEFT		'A'
#define     DIR_RIGHT		'D'
#define     START_STOP_V	'L'
#define		START_STOP_J	'V'
#define		INC_SPEED		'Q'
#define		DEC_SPEED		'T'
#define		FRONT_LIGHT		'X'
// -----

boolean stopped;

byte speed;

char data;

void forward() {
	digitalWrite(DIR_A, LOW);
	digitalWrite(DIR_B, LOW);
}

void backward() {
	digitalWrite(DIR_A, HIGH);
	digitalWrite(DIR_B, HIGH);
}

void rotateleft() {
	digitalWrite(DIR_A, LOW);
	digitalWrite(DIR_B, HIGH);
}

void rotateright() {
	digitalWrite(DIR_A, HIGH);
	digitalWrite(DIR_B, LOW);
}

void stop() {
	analogWrite(PWM_LEFT, 0);
	analogWrite(PWM_RIGHT, 0);
}

void setspeed(boolean sp) {
	if (sp) {
		if (speed < MAX_SPEED) {
			speed += 50;
			analogWrite(PWM_LEFT, speed);
			analogWrite(PWM_RIGHT, speed);
		}
	}
	else
	{
		if (speed > MIN_SPEED) {
			speed -= 50;
			analogWrite(PWM_LEFT, speed);
			analogWrite(PWM_RIGHT, speed);
		}
	}
}

void setlight() {
	digitalWrite(LED_LIGHT, !(digitalRead(LED_LIGHT)));
}

boolean isborder() {
	if (!((digitalRead(BORDER_L) == LOW) && (digitalRead(BORDER_R) == LOW)))
		return true;
	else
		return false;
}

void setup() {
	pinMode(PWM_LEFT, OUTPUT);
	pinMode(PWM_RIGHT, OUTPUT);
	pinMode(DIR_A, OUTPUT);
	pinMode(DIR_B, OUTPUT);
	pinMode(LED_LIGHT, OUTPUT);

	pinMode(BORDER_L, INPUT);
	pinMode(BORDER_R, INPUT);

	digitalWrite(LED_LIGHT, LOW);

	stopped = true;

	speed = MIN_SPEED;

	Serial.begin(9600);
}

void loop() {
	if (Serial.available()) {

		data = Serial.read();

		if ((data == START_STOP_J) || (data == START_STOP_V)) {
			if (stopped) {
				forward();

				analogWrite(PWM_LEFT, speed);
				analogWrite(PWM_RIGHT, speed);

				stopped = false;
			}
			else
			{
				stop();
				stopped = true;
			}
		}

		switch (data) {
			case DIR_FORWARD:
				if (!stopped)
					forward();
				break;

			case DIR_BACKWARD:
				if (!stopped)
					backward();
				break;

			case DIR_LEFT:
				if (!stopped)
					rotateleft();
				break;

			case DIR_RIGHT:
				if (!stopped)
					rotateright();
				break;

			case INC_SPEED:
				if (!stopped)
					setspeed(true);
				break;

			case DEC_SPEED:
				if (!stopped)
					setspeed(false);
				break;

			case FRONT_LIGHT:
				setlight();
				break;

			default:
				break;
		}
	}

	if (isborder())
		stop();
}

Ahora procedemos a conectar nuestro módulo Módulo Bluetooth HC-07 de la siguiente manera:

Módulo Bluetooth HC-07 –> Arduino Uno R3
TX      –>   D0 (RX)
RX     –>   D1 (TX)
5V     –>   5V
GND  –>  GND

Ahora encenderemos nuestro robot y lo buscamos en nuestro teléfono móvil/tablet (normalmente con el nombre “HC-07“, aunque esto puede variar) y lo emparejaremos con nuestro dispositivo, la contraseña por defecto es “1234” (sin comillas) o “0000” (sin comillas). En la siguiente imagen observamos nuestro dispositivo emparejado con nuestro robot:

Habiendo finalizado exitosamente el paso anterior, el cual es fundamental para continuar, ahora lanzaremos la aplicación “Arduino Bluetooth Controller“, que aparecerá en nuestro teléfono móvil/tablet con el nombre “ArduinoRC“, observaremos lo que se muestra en la siguiente imagen:

Presionamos el botón “Proceed“.
Luego nos aparecerá una lista de los dispositivos emparejados a nuestro teléfono móvil/tablet. Seleccionamos nuestro robot:

Si la conexión se estableció correctamente, nos aparecerá lo que observamos en la siguiente imagen y presionamos el botón “Vehicle Mode“:

Ahora debemos personalizar la configuración de la aplicación, para esto debemos presionar el menú desplegable y seleccionar la opción “Set Commands“, como se muestra en la siguiente imagen:

Ahora procedemos a personalizar la configuración según las siguientes imágenes:

Finalizada exitosamente la configuración, podremos controlar los movimientos de nuestro robot utilizando el giroscopio y acelerómetro de nuestro teléfono móvil/tablet. El botón de Android controla “Inicio/Parada” de nuestro robot.

Habiendo configurado y verificado el correcto funcionamiento de este modo de control, a continuación regresaremos al inicio de nuestra aplicación y presionaremos el botón “Controller Mode“.

Ahora debemos personalizar la configuración de la aplicación, para esto debemos presionar el menú desplegable y seleccionar la opción “Set Commands“, como se muestra en la siguiente imagen:

Ahora procedemos a personalizar la configuración según las siguientes imágenes:

Finalizada exitosamente la configuración, podremos controlar los movimientos de nuestro robot utilizando el joystick táctil de la aplicación. En la siguiente imagen observamos la función de cada botón del joystick:


Los robots seguidores de línea son robots muy sencillos, que cumplen una única misión: seguir una línea marcada en el suelo normalmente de color negro sobre un tablero blanco (normalmente una línea negra sobre un fondo blanco). Son considerados los “Hola mundo” de la robótica.

Estos robots pueden variar desde los más básicos (van tras una línea única) hasta los robots que recorren laberintos, como el que construiremos en esta publicación. Todos ellos, sin embargo, poseen (por lo general) ciertas partes básicas comunes entre todos:

Sensores: Un rastreador detecta la línea a seguir por medio de sensores. Hay muchos tipos de sensores que se pueden usar para este fin; sin embargo, por razones de costos y practicidad, los más comunes son los sensores infrarrojos (IR), que normalmente constan de un LED infrarrojo y un fototransistor, la línea a seguir, puede ser de color negro con fondo blanco o línea blanca con fondo negro. Nuestro robot ofrecerá ambas opciones modificando simplemente un par de líneas en su código fuente. Utilizaremos 4 módulos detectores cuyo componente principal será el sensor óptico reflectivo TCRT5000 fabricado por Vishay Semiconductors, el cual incluye un filtro que bloquea la luz visible (luz ambiente) lo cual nos evitará varios dolores de cabeza y riesgos de ACV. En las siguientes imágenes observamos el sensor y su correspondiente módulo ya ensamblado. La tensión de alimentación es de 5V que obtendremos de nuestra tarjeta de control Arduino UNO R3 y dicho módulo entrega un valor lógico alto [1] cuando no se refleja la luz infrarroja en la superficie y un valor lógico bajo [0] cuando existe reflejo.

Motores: El robot se mueve utilizando motores. Dependiendo del tamaño, el peso, la precisión del motor, entre otros factores, éstos pueden ser de varias clases: motores de corriente continua (nuestro robot), motores paso a paso o servomotores liberados para giro continuo.

Ruedas: Las ruedas del robot son movidas por los motores. Normalmente se usan ruedas de materiales anti-deslizantes para evitar fallas de tracción. Su tamaño es otro factor a tener en cuenta a la hora de armar el robot.

Fuente de energía: El robot obtiene la energía que necesita para su funcionamiento de baterías o de una fuente de corriente alterna, siendo esta última menos utilizada debido a que le resta independencia al robot.

Tarjeta de control: La toma de decisiones y el control de los motores están generalmente a cargo de un microcontrolador. La tarjeta de control contiene dicho elemento, junto a otros componentes electrónicos básicos que requiere el microcontrolador para funcionar. Utilizaremos una tarjeta de control Arduino Uno R3 en nuestro robot.

Todos los rastreadores basan su funcionamiento en los sensores. Sin embargo, dependiendo de la complejidad del recorrido, el robot debe ser más o menos complejo (y, por ende, utilizar más o menos sensores).

Los rastreadores más simples utilizan 2 sensores, ubicados en la parte inferior de la estructura, uno junto al otro. Cuando uno de los dos sensores detecta el color blanco, significa que el robot está saliendo de la línea negra por ese lado. En ese momento, el robot gira hacia el lado contrario hasta que vuelve a estar sobre la línea. Esto en el caso de los seguidores de línea negra, ya que también hay seguidores de línea blanca. Como se mencionó anteriormente, nuestro robot ofrecerá ambas opciones modificando simplemente un par de líneas en su código fuente.

Lista de Componentes
1 Plataforma Turtle2WD con placa Arduino UNO R3 y Shield de Control de Motores ensamblados anteriormente.
4 Módulos Detectores con Sensor Óptico Reflectivo TCRT5000.
4 Separadores Plásticos 5mm
1 Papel Afiche 100cm x 70cm
1 Rollo de Cinta de Papel Color Blanco 10mm

En primer lugar debemos instalar los cuatro módulos detectores en la parrilla de montaje de sensores de la plataforma Turtle2WD como se observa en las siguientes imágenes:

(click para ampliar)

(click para ampliar)

(click para ampliar)

(click para ampliar)

IMPORTANTE: lo que haremos a continuación es crucial para el correcto funcionamiento del robot. Conectaremos a la placa Arduino los cuatro módulos detectores respetando la numeración y nomenclatura utilizada a continuación que se corresponde con el código fuente provisto, de lo contrario el funcionamiento del robot será errático.

Vista trasera de la plataforma Turtle2WD, de izquierda a derecha (parte frontal de la plataforma: portapilas).

Sensor Izquierdo Externo (Salida “D0”)  –>  A2
Sensor Izquierdo Interno (Salida “D0”)  –>  A3
Sensor Derecho Interno (Salida “D0”)    –>  A4
Sensor Derecho Externo (Salida “D0”)    –>  A5

Los pines “A0” de todos los módulos quedan sin conexión ya que son las salidas analógicas de los sensores y no las utilizaremos en este caso.

Los pines “GND” y “VCC” (5V), los conectaremos a sus correspondientes pines “GND” y “5V” en la placa Arduino para suministrarles una tensión de 5V a cada módulo.

Habiendo conectado correctamente los cuatro sensores reflectivos, sólo resta compilar y cargar en nuestro Arduino UNO R3 el sketch correspondiente, cuyo código fuente se encuentra a continuación:

/*
Caracteristicas:
- Seguidor de Linea (LINEA BLANCA/FONDO NEGRO) o (LINEA NEGRA/FONDO BLANCO).
*/

// Control de Motores: Direccion y Velocidad
// Vista desde atras del movil, de izquierda a derecha
// Parte frontal del movil: Portapilas
#define     PWM_RIGHT   3     // (Control Velocidad Motor Derecho) Timer2 8 bits D3
#define     PWM_LEFT    11    // (Control Velocidad Motor Izquierdo) Timer2 8bits D11
#define     DIR_A       12    // (Control de Direccion de Motores) D12
#define     DIR_B       13    // (Control de Direccion de Motores) D13
// -----

// Sensores Reflectivos
// Vista desde atras del movil, de izquierda a derecha
// Parte frontal del movil: Portapilas
#define     SENSOR_LO   A2    // (Sensor Izquierdo Externo)
#define     SENSOR_LI   A3    // ((Sensor Izquierdo Interno))
#define     SENSOR_RI   A4    // (Sensor Derecho Interno)
#define     SENSOR_RO   A5    // (Sensor Derecho Externo)
// -----

// -----

#define    WEIGHT_LO    8
#define    WEIGHT_LI    4
#define    WEIGHT_RI    2
#define    WEIGHT_RO    1

#define    VMAX         90 //PWM
#define    REDUCTF      0.1f

#define    BLACK        1
#define    WHITE        0

#define    BACKGROUND   BLACK
#define    LINE         WHITE

byte state, leftwheel, rightwheel;

void scan() {
    state = ((digitalRead(SENSOR_LO) == LINE) * WEIGHT_LO) + ((digitalRead(SENSOR_LI) == LINE) * WEIGHT_LI) + ((digitalRead(SENSOR_RI) == LINE) * WEIGHT_RI) + ((digitalRead(SENSOR_RO) == LINE) * WEIGHT_RO);
}

void forward() {
    rightwheel = VMAX;
    leftwheel = VMAX;
    analogWrite(PWM_RIGHT, rightwheel);
    analogWrite(PWM_LEFT, leftwheel);
}

void turnleft() {
    leftwheel = 0;
    rightwheel = VMAX;
    analogWrite(PWM_RIGHT, rightwheel);
    analogWrite(PWM_LEFT, leftwheel);
    
	do {
        scan();
    } while(state != 2 && state != 6);
    //} while(state < 8);
    //} while(state != 2;
}

void turnright() {
    leftwheel = VMAX;
    rightwheel = 0;
    analogWrite(PWM_RIGHT, rightwheel);
    analogWrite(PWM_LEFT, leftwheel);

    do {
        scan();
    } while(state != 4 && state != 6);
    //} while(state != 4 && state != 6);
    //} while(state != 4 && state != 6);
}

void leftcorrection() {
    leftwheel = leftwheel - leftwheel * REDUCTF;
    rightwheel = VMAX;
    analogWrite(PWM_RIGHT, rightwheel);
    analogWrite(PWM_LEFT, leftwheel);
}

void rightcorrection() {
    rightwheel = rightwheel - rightwheel * REDUCTF;
    leftwheel = VMAX;
    analogWrite(PWM_RIGHT, rightwheel);
    analogWrite(PWM_LEFT, leftwheel);
}

void setup() {
    pinMode(PWM_RIGHT, OUTPUT);
    pinMode(PWM_LEFT, OUTPUT);
    pinMode(DIR_A, OUTPUT);
    pinMode(DIR_B, OUTPUT);

    pinMode(SENSOR_LO, INPUT);
    pinMode(SENSOR_LI, INPUT);
    pinMode(SENSOR_RI, INPUT);
    pinMode(SENSOR_RO, INPUT);

    digitalWrite(DIR_A, LOW);
    digitalWrite(DIR_B, LOW);
}

void loop() {
    scan();

    switch (state) {
        case 0:
            // 0000 -> FORWARD
            forward();
            break;

        case 1:
            // 0001 RIGHT CURVE -> TURN RIGHT
            turnright();
            break;

        case 2:
            // 0010 GOING LEFT -> RIGHT CORRECTION
            rightcorrection();
            break;

        case 3:
            // 0011 RIGHT CURVE -> TURN RIGHT
            turnright();
            break;

        case 4:
            // 0100 GOING RIGHT -> LEFT CORRECTION
            leftcorrection();
            break;

        // case 5:
            // // 0101 ???
            // break;

        // case 6:
            // 0110 GOING TO AN UNDEFINED SIDE -> NOTHING TO DO HERE
            // forward();
            // break;

        case 7:
            // 0111 RIGHT CURVE -> TURN RIGHT
            turnright();
            break;

        case 8:
            // 1000 LEFT COURVE -> TURN LEFT
            turnleft();
            break;

        case 9:
            // 1001
            turnright();
            break;

        // case 10:
            // 1010 ??? SHOULD NEVER HAPPEN SAME AS 5
            // break;

        // case 11:
            // // 1011 ??? SAME AS 13
            // break;

        case 12:
            // 1100 LEFT COURVE -> TURN LEFT
            turnleft();
            break;

        // case 13:
            // 1101 ??? SAME AS 11
            // break;

        case 14:
            // 1110 LEFT CURVE -> TURN LEFT SAME AS 7
            turnleft();
            break;

        case 15:
            // 1111 T -> TURN TO RIGHT
            turnright();
            break;

        default:
            // KEEP STATUS
            break;
    }
}

Finalmente, pegando la cinta de papel sobre el afiche diseñaremos el recorrido a realizar por nuestro robot, que puede ser desde una simple línea recta, un bucle en forma de “O”, o un laberinto como el que observamos en el vídeo que se encuentra la final de la publicación.
Antes de accionar el interruptor de encendido para que nuestro robot entre en acción debemos ubicarlo sobre el punto de partida de la siguiente manera:

(click para ampliar)

Dejando de lado, solo momentáneamente, los juegos construidos con Arduino publicados en las últimas cuatro entradas de este blog, retomaremos los proyectos de robótica ya que desde hace tiempo no hice publicaciones al respecto.

En esta ocasión quiero compartir la construcción de mi último robot, se trata de un robot araña cuadrúpedo con 8 DOF (Degrees Of Freedom – Grados De Libertad) construido con un total de nueve servomotores “TowerPro SG90”, de los cuales ocho están destinados a los movimientos y articulaciones de cada una de las patas y un servomotor adicional para controlar los movimientos de la cabeza del robot, en la cual se encuentra instalado un Sensor UltrasónicoHC-SR04” para detectar y evadir obstáculos. Para comandar nuestra araña emplearemos un Joystick Inalámbrico de Playstation 2 que seguramente tenemos alguno juntando tierra en algún cajón o bien podemos conseguir una versión genérica del mismo a un bajo costo. Este joystick es sencillo de conectar a nuestra placa Arduino ya que utiliza el protocolo SPI (Serial Peripheral Interface) y posee todas las características necesarias para comandar nuestro robot.

En el sitio web de Kaiwa Technology encontré un kit que se ajusta perfectamente a nuestros requerimientos. Si bien he realizado modificaciones personales que permiten obtener un mejor rendimiento, debo decir que el resultado final de este proyecto ha satisfecho ampliamente mis expectativas desde que decidí comenzar con la construcción de este robot. El kit es muy completo e incluye todos los componentes necesarios para el armado del mismo sin mayores dificultades. Los componentes que encontraremos en este kit son los siguientes:

Componentes de Electrónica

  • 1 Arduino Nano V3.0 (clon)
  • 1 Arduino Nano Shield
  • 1 Sensor Ultrasónico “HC-SR04
  • 9 Servomotores “TowerPro SG90
  • 1 Portabaterías AA x 4
  • 1 Cable USB 2.0 A Macho – Mini USB B Macho

Piezas Plásticas Impresas en 3D

  • 1 Cuerpo de Araña
  • 8 Piezas en “U
  • 4 Patas
  • 1 Cabeza

Además de los componentes incluidos en el kit, precisaremos los siguientes componentes adicionales NO INCLUIDOS en el kit:

  • 1 Joystick Inalámbrico de Playstation 2
  • 2 Capacitores Electrolíticos 1000uF 10V
  • 1 Capacitor Electrolítico 220uF 10V
  • 1 Capacitor Cerámico 100nF 50v
  • 1 Controlador de Posición de Servomotores
  • 4 Baterías Recargables AA Ni-Mh 1.2V 2700mAh
  • 1 Controlador de Posición de Servomotores
  • 1 Interruptor Tipo Palanca SPST 3A 250VAC
  • 1 Pomo de Pegamento “UHU” 35ml
  • 1 Lata de Adhesivo de Contacto EspecialFortex” 125cm3
  • Librería NewPing desarrollada por Tim Ecker
  • Librería Arduino-PS2X desarrollada por Bill Porter

En la siguiente imagen podemos observar los componentes incluidos en el kit:

(click para ampliar)

IMPORTANTE: los servomotores que forman parte del cuerpo llevan un solo tornillo al chasis, en caso de detectar que no sujetan lo suficiente, los mismos pueden ser pegados con pegamento “UHU“.

En la siguiente imagen observamos los primeros cuatro servomotores que se montarán en el cuerpo:

(click para ampliar)

Cada servo tiene su posición y numeración. Colocamos los 4 servos en sus lugares correspondientes, cada uno con su tornillo y pegamento “UHU” del lado opuesto que no posee tornillo para asegurarlo lo suficiente.

(click para ampliar)

A continuación ensamblamos las piezas en “U“, de manera tal que coincidan las tres perforaciones y las fijamos con sus tres tornillos y tuercas correspondientes como se muestra en la siguiente imagen:

(click para ampliar)

IMPORTANTE: antes de colocar cualquiera de las partes de los servomotores, debemos buscar la posición central del servomotor. Para lograr nuestro objetivo utilizaremos el Controlador de Posición de Servomotores. Alimentaremos el Controlador con una tensión de 5V, conectaremos el servomotor al Controlador y pulsaremos el botón “Select” del controlador hasta que el LED azul nos indique que se encuentra en la posición “Neutral” como se observa en la siguiente imagen:

(click para ampliar)

(click para ampliar)

Repetiremos la misma operación para los 3 servomotores restantes, de esta manera quedarán ubicados en su posición central.
Luego, centraremos las piezas en “U” de manera tal que las mismas queden en paralelo a los servomotores y luego colocaremos los brazos plásticos para fijarlas a cada servomotor.

(click para ampliar)

De la parte inferior colocamos los tornillos de soporte, y los ajustamos hasta que ejerzan cierta presión contra el servomotor. No presionar demasiado ya que el plástico no posee rosca.

(click para ampliar)

Ahora comenzaremos a ensamblar las patas, colocando un servomotor en cada una de las mismas. El eje del servomotor debe quedar en el extremo opuesto a la pata. Fijamos cada servomotor a cada una de las patas con su tornillo y pegamento “UHU” del lado opuesto que no posee tornillo para asegurarlo lo suficiente.

(click para ampliar)

A continuación instalaremos las patas teniendo en cuenta la numeración correspondiente. Cada pata se coloca de la misma manera como la pieza en “U” al servomotor del cuerpo central.

(click para ampliar)

Ahora instalaremos el último servomotor donde posteriormente fijaremos el Sensor Ultrasónico que se encuentra instalado en la pieza plástica que conforma el rostro de nuestro robot araña.

(click para ampliar)

Luego, fijaremos el brazo plástico más largo del servomotor al soporte (rostro de la araña) del Sensor Ultrasónico, como observamos en las siguientes imágenes:

(click para ampliar)

(click para ampliar)

Buscamos la posición neutral de este servomotor como ya lo hicimos anteriormente con los ocho servomotores anteriores y procedemos a atornillar el Sensor Ultrasónico.

(click para ampliar)

Imagen completa del robot y todas sus partes ensambladas con la nomenclatura correspondiente:

(click para ampliar)

A continuación pegaremos el portabaterías a la parte inferior del cuerpo de nuestro robot utilizando el Adhesivo de Contacto EspecialFortex” ya que se requiere una fijación resistente para soportar el peso de las baterías y la manipulación de las mismas. En la siguiente imagen se observa el portabaterías ya instalado:

(click para ampliar)

Habiendo ensamblado exitosamente la estructura siguiendo los pasos anteriores, en este punto comenzaremos con el montaje de la parte electrónica.
Un servomotor consta de un pequeño motor que hace girar una serie de engranajes dispuestos en árbol para aumentar el torque final del ultimo engranaje, esto es simplemente una “caja reductora”, en consecuencia, cuando se modifica el ángulo del servomotor lo que realmente se hace es enviar tensión al motor en forma de pulsos, “esto sucede internamente dentro del servo”. Si el brazo o leva del servomotor está sometido a una gran fuerza también consumirá más energía/corriente, ya que para mantener la posición demandada el motor interno estará todo el tiempo contrarrestando la fuerza que se ejerce sobre su brazo a base de ligeros impulsos de corriente hacia el motor interno.
Por lo tanto, necesitamos asegurarnos que no les faltará energía a los nueve servos que componen nuestro robot. Para lograr este objetivo instalaremos en el lateral izquierdo del portabaterías dos capacitores electrolíticos de 1000uF 10V conectados en paralelo, obteniendo en total 2000uF 10V. Luego soldaremos los cables de alimentación provenientes del portabaterías en paralelo a los capacitores electrolíticos respetando la polaridad de los mismos. Finalmente conectaremos el terminal positivo a un interruptor tipo palanca SPST instalado en la parte trasera del cuerpo de nuestro robot como se observa en las siguientes imágenes:

(click para ampliar)

(click para ampliar)

Luego insertaremos el “Arduino Nano V3.0” en su correspondiente “Arduino Nano Shield” y lo instalaremos en el cuerpo central del robot:

(click para ampliar)

IMPORTANTE: lo que haremos a continuación es crucial para el correcto funcionamiento del robot. Conectaremos al “Arduino Nano Shield” los nueve servomotores respetando la numeración y nomenclatura original provista en el kit y el receptor inalámbrico de Playstation 2 de acuerdo a la siguiente imagen:

En los pines de alimentación de 3.3V que utilizaremos para suministrar energía al receptor inalámbrico de Playstation 2, también debemos insertar en paralelo aGNDy3.3Vdos capacitores: un capacitor electrolítico de 220uF 10V y un capacitor cerámico de 100nF 50V como se muestra en la siguiente imagen:

(click para ampliar)

Habiendo finalizado exitosamente el armado de la estrucutra y conectado correctamente los servomotores, el Sensor Ultrasónico y el Receptor Inalamábrico de Playstation 2, sólo resta compilar y cargar en nuestro Arduino Nano el sketch correspondiente, cuyo código fuente se encuentra a continuación:
(No olvidar descargar y agregar las librerías NewPing y Arduino-PS2X)

#include <Servo.h>
#include <NewPing.h>
#include <PS2X_lib.h>

#define TRIG_PIN        A0
#define ECHO_PIN        A1
#define MAX_DISTANCE    400

//-------------------------------------------------------------------
//  Definicion de las constantes posicion inicial de cada servo
//-------------------------------------------------------------------
//subir = giro antihor en cuerpo y patas

#define FIC_centro  1100     //Frente_Izquierda_cuerpo_centro
#define FDC_centro  1700     //Frente_derecha_cuerpo_centro
#define AIC_centro  1800     //Atras_Izquierda_cuerpo_centro
#define ADC_centro  1250     //Atras_derecha_cuerpo_centro

#define FIP_centro  800      //Frente_Izquierda_pata_centro
#define FDP_centro  800      //Frente_derecha_pata_centro
#define AIP_centro  700      //Atras_Izquierda_pata_centro
#define ADP_centro  600      //Atras_derecha_pata_centro

//-------------------------------------------------------------------
//      Definicion Alias de cada servo y los Pines del Arduino
//-------------------------------------------------------------------
#define FIC_pin             4     // Pin Frente Izquierda Cuerpo
#define FDC_pin             7     // Pin Frente Derecha Cuerpo
#define AIC_pin             5     // Pin Atras Izquierda Cuerpo
#define ADC_pin             6     // Pin Atras Derecha Cuerpo
#define FIP_pin             8     // Pin Frente Izquierda Pata
#define FDP_pin             11    // Pin Frente Derecha Pata
#define AIP_pin             9     // Pin Atras Izquierda Pata
#define ADP_pin             10    // Pin Atras Derecha Pata
#define Cabeza_pin          3
#define pulsador_arranque   12    //defino donde va conectado el pulsador de arranque
//-------------------------------------------------------------------

PS2X ps2x; // create PS2 Controller Class

NewPing sonar(TRIG_PIN, ECHO_PIN, MAX_DISTANCE);

//-------------------------------------------------------------------
//Con este timer se setea la velocidad de movimiento de todo el robot, mas chico, mas rapido
//-------------------------------------------------------------------
int Time = 100;

int movimiento_izq;
int movimiento_der;
int levanta=-400;

int contador_sentarse;
int distancia_actual = 0;
int pos = 90;

int max_der = 0;
int max_izq = 0;
int aux = 0;    //auxiliar que utilizo para las funciones especiales
int variable_sienta = 800;

const int tiempo_entre_servo = 5;
const int tiempo_sienta = 50;

const int margen_joystick = 10;      //margen que tiene el joystick para saber si esta corrido del centro

int variable_control = 0;   //variable que indica que comando fue pulsado en el PS2

//-------------------------------------------------------------------
//       Defino como le va a llamar cada servo
//-------------------------------------------------------------------
Servo FIC_servo;                                               // Front Left  Hip
Servo FDC_servo;                                               // Front Right Hip
Servo AIC_servo;                                               // Rear  Left  Hip
Servo ADC_servo;                                               // Rear  Right Hip
Servo FIP_servo;                                               // Front Left  Knee
Servo FDP_servo;                                               // Front Right Knee
Servo AIP_servo;                                               // Rear  left  Knee
Servo ADP_servo;                                               // Rear  Right Knee
Servo Cabeza_servo;

//-------------------------------------------------------------------------------------
//       funcion para volver a la posicion inicial despues de cada movimiento
//-------------------------------------------------------------------------------------
void posicion_reposo() {

    int tiempo = 20;
    FIC_servo.writeMicroseconds(FIC_centro);       // envia servo a su posicion inicial
    delay(tiempo);
    FDC_servo.writeMicroseconds(FDC_centro);
    delay(tiempo);
    AIC_servo.writeMicroseconds(AIC_centro);
    delay(tiempo);
    ADC_servo.writeMicroseconds(ADC_centro);
    delay(tiempo);
    FIP_servo.writeMicroseconds(FIP_centro);
    delay(tiempo);
    FDP_servo.writeMicroseconds(FDP_centro);
    delay(tiempo);
    AIP_servo.writeMicroseconds(AIP_centro);
    delay(tiempo);
    ADP_servo.writeMicroseconds(ADP_centro);
    delay(tiempo);
    Cabeza_servo.write(90);
}

//-------------------------------------------------------------------
//             Funcion Avanzar hacia el frente
//-------------------------------------------------------------------
void Camina_frente() {

    if ((movimiento_izq < 0) && (movimiento_der < 0)) {
        Cabeza_servo.write(110);
        decide_costados();
    }

    FDP_servo.writeMicroseconds(FDP_centro-levanta);                // raise front right leg
    delay(tiempo_entre_servo);
    AIP_servo.writeMicroseconds(AIP_centro-levanta);                // raise rear  left  leg
    delay(tiempo_entre_servo);
    FIC_servo.writeMicroseconds(FIC_centro-movimiento_izq);         // move  front left  leg backward
    delay(tiempo_entre_servo);
    ADC_servo.writeMicroseconds(ADC_centro+movimiento_der);         // move  rear  right leg backward
    delay(Time/2);
    FDC_servo.writeMicroseconds(FDC_centro-movimiento_der);         // move  front right leg forward
    delay(tiempo_entre_servo);
    AIC_servo.writeMicroseconds(AIC_centro+movimiento_izq);         // move  rear  left  leg forward
    delay(Time);
    FDP_servo.writeMicroseconds(FDP_centro);                        // lower front right leg
    delay(tiempo_entre_servo);
    AIP_servo.writeMicroseconds(AIP_centro);                        // lower rear  left  leg
    delay(Time);

    if ((movimiento_izq < 0) && (movimiento_der < 0)) {
        Cabeza_servo.write(70);
        decide_costados();
    }

    FIP_servo.writeMicroseconds(FIP_centro-levanta);                // raise front left  leg
    delay(tiempo_entre_servo);
    ADP_servo.writeMicroseconds(ADP_centro-levanta);                // raise rear  right leg
    delay(tiempo_entre_servo);
    FDC_servo.writeMicroseconds(FDC_centro+movimiento_der);         // move  front right leg backward
    delay(tiempo_entre_servo);
    AIC_servo.writeMicroseconds(AIC_centro-movimiento_izq);         // move  rear  left  leg backward
    delay(Time/2);
    FIC_servo.writeMicroseconds(FIC_centro+movimiento_izq);         // move  front left  leg forward
    delay(tiempo_entre_servo);
    ADC_servo.writeMicroseconds(ADC_centro-movimiento_der);         // move  rear  right leg forward
    delay(Time);
    FIP_servo.writeMicroseconds(FIP_centro);                        // lower front left  leg
    delay(tiempo_entre_servo);
    ADP_servo.writeMicroseconds(ADP_centro);                        // lower rear  right leg
    delay(Time);
}

//-------------------------------------------------------------------
//            Funcion que lee el sensor frontal
//-------------------------------------------------------------------
unsigned int readPing() {                           //funcion para leer US y pasarlo a cm
    unsigned int uS = sonar.ping();
    delay(100);

    return (uS/US_ROUNDTRIP_CM);
}

//-------------------------------------------------------------------
//                    Elije para donde avanzar
//-------------------------------------------------------------------
void decide_costados() {

    delay(50);
    distancia_actual = readPing();

    if ((distancia_actual < 30) && (distancia_actual > 10)) {      //chequeo si obstaculo esta entre 10 y 30 cm
        mira_costados();                             //encontrar la salida
    }

    if ((distancia_actual < 10) && (distancia_actual != 0)) {      //chequea obstaculo menor a 10cm
        camina_atras();                               //hace secuancia para atras
    }

}

//-------------------------------------------------------------------
//  Mide para los costados para despues decidir hacia donde avanzar
//-------------------------------------------------------------------
void mira_costados() {                        //hace un barrido y decide para donde ir

    delay(90);
    max_der = 0;
    max_izq = 0;

    for(pos = 144; pos >= 36; pos-= 36) {    // goes from 180 degrees to 0 degrees

        Cabeza_servo.write(pos);                 // tell servo to go to position in variable 'pos'
        delay(90);
        distancia_actual = readPing();                 //lee ultrasonido

        if ((pos > 90) && (distancia_actual > max_izq)) {   // si es mayor al maximo izquierda lo actualiza
            max_izq = distancia_actual;
        }

        if ((pos < 90) && (distancia_actual > max_der)) {  // si es mayor al maximo derecha lo actualiza
            max_der = distancia_actual;
        }
    }

    Cabeza_servo.write(90);                //posiciona servo en el medio

    if (max_der > max_izq) {
        Gira_der();                       //gira derecha
    }

    if (max_izq > max_der) {
        Gira_izq();                      //gira izquierda
    }
}

//-------------------------------------------------------------------
//                 Gira Derecha
//-------------------------------------------------------------------
void Gira_der() {
    movimiento_izq=300;
    movimiento_der=-300;
    Camina_frente();
}

//-------------------------------------------------------------------
//                 Gira Izquierda
//-------------------------------------------------------------------
void Gira_izq() {
    movimiento_izq=-300;
    movimiento_der=300;
    Camina_frente();
}

//-------------------------------------------------------------------
//               Camina hacia atras
//-------------------------------------------------------------------
void camina_atras() {
    movimiento_izq=300;
    movimiento_der=300;
    Camina_frente();
}

//-------------------------------------------------------------------
//                  Funcion Sentarse
//-------------------------------------------------------------------
void sienta() {

    FDC_servo.writeMicroseconds(FDC_centro);
    delay(Time/2);
    FIC_servo.writeMicroseconds(FIC_centro);
    delay(Time/2);

    ADC_servo.writeMicroseconds(ADC_centro+variable_sienta/3);  //se tira de a poco
    delay(Time/2);
    AIC_servo.writeMicroseconds(AIC_centro-variable_sienta/3);
    delay(Time/2);
    ADP_servo.writeMicroseconds(ADP_centro+variable_sienta/3);
    delay(Time/2);
    AIP_servo.writeMicroseconds(AIP_centro+variable_sienta/3);
    delay(Time/2);

    ADC_servo.writeMicroseconds(ADC_centro+variable_sienta/2);  //se tira de a poco
    delay(Time/2);
    AIC_servo.writeMicroseconds(AIC_centro-variable_sienta/2);
    delay(Time/2);
    ADP_servo.writeMicroseconds(ADP_centro+variable_sienta/2);
    delay(Time/2);
    AIP_servo.writeMicroseconds(AIP_centro+variable_sienta/2);
    delay(Time/2);

    ADC_servo.writeMicroseconds(ADC_centro+variable_sienta);   //se termina de tirar
    delay(Time/2);
    AIC_servo.writeMicroseconds(AIC_centro-variable_sienta);
    delay(Time/2);
    ADP_servo.writeMicroseconds(ADP_centro+variable_sienta);
    delay(Time/2);
    AIP_servo.writeMicroseconds(AIP_centro+variable_sienta);
    delay(Time/2);

    delay(10);
}

void mueve_cabeza() {

    Cabeza_servo.write(45);
    delay(3*Time);
    Cabeza_servo.write(135);
    delay(3*Time);
    Cabeza_servo.write(90);
    delay(3*Time);
}

void sentado_levanta() {

    mueve_cabeza();

    FIP_servo.writeMicroseconds(FIP_centro);
    delay(Time/2);
    FDP_servo.writeMicroseconds(FDP_centro);
    delay(Time/2);
    FIC_servo.writeMicroseconds(FIC_centro);
    delay(Time/2);
    FDC_servo.writeMicroseconds(FDC_centro);
    delay(Time/2);
    AIP_servo.writeMicroseconds(AIP_centro);
    delay(Time/2);
    ADP_servo.writeMicroseconds(ADP_centro);
    delay(Time/2);
    AIC_servo.writeMicroseconds(AIC_centro);                      // center servos
    delay(Time/2);
    ADC_servo.writeMicroseconds(ADC_centro);

    delay(10);
}

//-------------------------------------------------------------------
//                  Funcion Saluda
//-------------------------------------------------------------------
void saluda() {

    FDC_servo.writeMicroseconds(FDC_centro);
    delay(Time/2);
    FIC_servo.writeMicroseconds(FIC_centro);
    delay(Time/2);

    ADC_servo.writeMicroseconds(ADC_centro+variable_sienta);  //se tira al piso de costado
    delay(Time/2);
    AIC_servo.writeMicroseconds(AIC_centro-variable_sienta);
    delay(Time/2);

    FDP_servo.writeMicroseconds(2550);
    delay(Time/2);
    ADP_servo.writeMicroseconds(ADP_centro+variable_sienta/3);
    delay(Time/2);
    AIP_servo.writeMicroseconds(AIP_centro+variable_sienta/3);
    delay(Time/2);
    AIP_servo.writeMicroseconds(AIP_centro+variable_sienta/2);
    delay(Time/2);
    AIP_servo.writeMicroseconds(AIP_centro+variable_sienta);
    delay(Time/2);

    delay(10);
}

void saluda_levanta() {

    mueve_cabeza();

    FIP_servo.writeMicroseconds(FIP_centro);
    delay(Time/2);
    FDP_servo.writeMicroseconds(FDP_centro);
    delay(Time/2);
    FIC_servo.writeMicroseconds(FIC_centro);
    delay(Time/2);
    FDC_servo.writeMicroseconds(FDC_centro);
    delay(Time/2);
    AIP_servo.writeMicroseconds(AIP_centro);
    delay(Time/2);
    ADP_servo.writeMicroseconds(ADP_centro);
    delay(Time/2);
    AIC_servo.writeMicroseconds(AIC_centro);                      // center servos
    delay(Time/2);
    ADC_servo.writeMicroseconds(ADC_centro);

    delay(10);
}

//-------------------------------------------------------------------
//                  Funcion Mueve Pata en Frente
//-------------------------------------------------------------------
void mueve_pata_frente() {

    int maximo = 500;

    for(int j = 0; j<maximo; j = j + 100) {
        FDC_servo.writeMicroseconds(FDC_centro+j);  //se tira al piso de costado
        delay(Time/2);
    }

    for(int j = maximo; j>0; j = j - 100) {
        FDC_servo.writeMicroseconds(FDC_centro+j);  //se tira al piso de costado
        delay(Time/2);
    }

    for(int j = 0; j<maximo; j= j + 100) {
        FDC_servo.writeMicroseconds(FDC_centro-j);  //se tira al piso de costado
        delay(Time/2);
    }

    for(int j = maximo; j > 0; j = j - 100) {
        FDC_servo.writeMicroseconds(FDC_centro-j);  //se tira al piso de costado
        delay(Time/2);
    }
}

//-------------------------------------------------------------------
//                  Funcion Alaba y se queda abajo
//-------------------------------------------------------------------
void alaba() {

    ADC_servo.writeMicroseconds(ADC_centro);
    delay(Time/2);
    AIC_servo.writeMicroseconds(AIC_centro);
    delay(Time/2);

    FDC_servo.writeMicroseconds(FDC_centro+variable_sienta);   //se termina de tirar
    delay(Time/2);
    FIC_servo.writeMicroseconds(FIC_centro-variable_sienta);
    delay(Time/2);
    FDP_servo.writeMicroseconds(FDP_centro+variable_sienta);
    delay(Time/2);
    FIP_servo.writeMicroseconds(FIP_centro+variable_sienta);
    delay(Time/2);

    delay(10);
}

void alaba_levanta() {

    FIP_servo.writeMicroseconds(FIP_centro);
    delay(Time/2);
    FDP_servo.writeMicroseconds(FDP_centro);
    delay(Time/2);
    FIC_servo.writeMicroseconds(FIC_centro);
    delay(Time/2);
    FDC_servo.writeMicroseconds(FDC_centro);
    delay(Time/2);
    AIP_servo.writeMicroseconds(AIP_centro);
    delay(Time/2);
    ADP_servo.writeMicroseconds(ADP_centro);
    delay(Time/2);
    AIC_servo.writeMicroseconds(AIC_centro);                      // center servos
    delay(Time/2);
    ADC_servo.writeMicroseconds(ADC_centro);

    delay(10);
}

//-------------------------------------------------------------------
//                  Funcion angelito
//-------------------------------------------------------------------
void angelito_cae() {

    FDC_servo.writeMicroseconds(FDC_centro+variable_sienta);   //se termina de tirar
    delay(Time/2);
    FIC_servo.writeMicroseconds(FIC_centro-variable_sienta);
    delay(Time/2);
    FDP_servo.writeMicroseconds(FDP_centro+variable_sienta);
    delay(Time/2);
    FIP_servo.writeMicroseconds(FIP_centro+variable_sienta);
    delay(Time/2);

    ADC_servo.writeMicroseconds(ADC_centro-variable_sienta);   //se termina de tirar
    delay(Time/2);
    AIC_servo.writeMicroseconds(AIC_centro+variable_sienta);
    delay(Time/2);
    ADP_servo.writeMicroseconds(ADP_centro+variable_sienta);
    delay(Time/2);
    AIP_servo.writeMicroseconds(AIP_centro+variable_sienta);
    delay(Time/2);
}

void angelito_saluda() {

    int maximo = 600;

    for(int j = 0; j < maximo; j = j + 100) {
        FDC_servo.writeMicroseconds(FDC_centro+j);  //se tira al piso de costado
        FIC_servo.writeMicroseconds(FIC_centro-j);  //se tira al piso de costado
        ADC_servo.writeMicroseconds(ADC_centro-j);  //se tira al piso de costado
        AIC_servo.writeMicroseconds(AIC_centro+j);  //se tira al piso de costado
        delay(Time/2);
    }

    for(int j = maximo; j > 0; j = j - 100) {
        FDC_servo.writeMicroseconds(FDC_centro+j);  //se tira al piso de costado
        FIC_servo.writeMicroseconds(FIC_centro-j);  //se tira al piso de costado
        ADC_servo.writeMicroseconds(ADC_centro-j);  //se tira al piso de costado
        AIC_servo.writeMicroseconds(AIC_centro+j);  //se tira al piso de costado
        delay(Time/2);
    }

    for(int j = 0; j < maximo; j = j + 100) {
        FDC_servo.writeMicroseconds(FDC_centro-j);  //se tira al piso de costado
        FIC_servo.writeMicroseconds(FIC_centro+j);  //se tira al piso de costado
        ADC_servo.writeMicroseconds(ADC_centro+j);  //se tira al piso de costado
        AIC_servo.writeMicroseconds(AIC_centro-j);  //se tira al piso de costado
        delay(Time/2);
    }

    for(int j = maximo; j > 0; j = j - 100) {
    FDC_servo.writeMicroseconds(FDC_centro-j);  //se tira al piso de costado
    FIC_servo.writeMicroseconds(FIC_centro+j);  //se tira al piso de costado
    ADC_servo.writeMicroseconds(ADC_centro+j);  //se tira al piso de costado
    AIC_servo.writeMicroseconds(AIC_centro-j);  //se tira al piso de costado
    delay(Time/2);
    }
}
//-------------------------------------------------------------------------------------
void lectura_control() {

    ps2x.read_gamepad(false, 0);      //read controller and set large motor to spin at 'vibrate' speed

    //-------------------------------------lectura de los Botones------------------------------------------------
    variable_control = 0;

    if(ps2x.ButtonPressed(PSB_START)) {
        variable_control = 1;

        return;
    }

    if(ps2x.ButtonPressed(PSB_SELECT)) {
        variable_control = 2;

        return;
    }

    if(ps2x.ButtonPressed(PSB_L3)) {
        variable_control = 3;

        return;
    }

    if(ps2x.ButtonPressed(PSB_R3)) {
        variable_control = 4;

        return;
    }

    if(ps2x.ButtonPressed(PSB_L2)) {
        variable_control = 5;

        return;
    }

    if(ps2x.Button(PSB_R2)) {
        variable_control = 6;

        return;
    }

    if(ps2x.Button(PSB_GREEN)) { //triangulo
        variable_control = 7;

        return;
    }

    if(ps2x.Button(PSB_RED)) {  //circulo
        variable_control = 8;

        return;
    }

    if(ps2x.Button(PSB_BLUE)) {  //x
        variable_control = 9;

        return;
    }

    if(ps2x.Button(PSB_PINK)) {  //cuadrado
        variable_control = 10;

        return;
    }

    if(ps2x.Button(PSB_PAD_UP)) {  //boton arriba
        variable_control = 11;

        return;
    }

    if(ps2x.Button(PSB_PAD_DOWN)) {   //boton abajo
        variable_control = 12;

        return;
    }

    if(ps2x.Button(PSB_PAD_LEFT)) {  //boton izquierda
        variable_control = 13;

        return;
    }

    if(ps2x.Button(PSB_PAD_RIGHT)) {  //boton derecha
        variable_control = 14;

        return;
    }

    if(ps2x.ButtonPressed(PSB_L1)) {
        variable_control = 23;

        return;
    }

    if(ps2x.ButtonPressed(PSB_R1)) {
        variable_control = 24;
        return;
    }
}

//-------------------------------------------------------------------
//                 Seteo de Entradas, salidas y funciones
//-------------------------------------------------------------------
void setup() {
    //-------------------------------------------------------------------
    // Inicializo Los servos con los nombres y cual es su pin asociado
    //-------------------------------------------------------------------
    FIC_servo.attach(FIC_pin);           //define los servos con su pin
    FDC_servo.attach(FDC_pin);
    AIC_servo.attach(AIC_pin);
    ADC_servo.attach(ADC_pin);
    FIP_servo.attach(FIP_pin);
    FDP_servo.attach(FDP_pin);
    AIP_servo.attach(AIP_pin);
    ADP_servo.attach(ADP_pin);
    Cabeza_servo.attach(Cabeza_pin);

    ps2x.config_gamepad(A2, A4, A3, A5, true, true);   //clock, command, attention, data

    //-------------------------------------------------------------------
    //         Arranco Todos los Servos en sus posiciones iniciales
    //-------------------------------------------------------------------
    FIC_servo.writeMicroseconds(FIC_centro);       // envia servo a su posicion inicial
    delay(tiempo_entre_servo);
    FDC_servo.writeMicroseconds(FDC_centro);
    delay(tiempo_entre_servo);
    AIC_servo.writeMicroseconds(AIC_centro);
    delay(tiempo_entre_servo);
    ADC_servo.writeMicroseconds(ADC_centro);
    delay(tiempo_entre_servo);
    FIP_servo.writeMicroseconds(FIP_centro);
    delay(tiempo_entre_servo);
    FDP_servo.writeMicroseconds(FDP_centro);
    delay(tiempo_entre_servo);
    AIP_servo.writeMicroseconds(AIP_centro);
    delay(tiempo_entre_servo);
    ADP_servo.writeMicroseconds(ADP_centro);
    delay(tiempo_entre_servo);
    Cabeza_servo.write(90);

    delay(500);
}

//-------------------------------------------------------------------
//         Sector donde comienza la funcion Principal,
//        Donde se va a quedar el resto de la ejecucion
//-------------------------------------------------------------------
void loop() {

    lectura_control();  //lectura del control PS2

    if(variable_control == 0) { //si no llegan comandos de la PS2 hago nada

        posicion_reposo();
    }

//-------------comandos de habilidades especiales----------------------------

//--------------------------se pulsa triangulo  ---------------------------------

    while(variable_control == 7) {  //fue pulsado triangulo

        if(aux == 0)
            sienta();

        aux = 1;
        delay(10);
        lectura_control();

        while(variable_control == 7) {  //fue pulsado triangulo
            delay(10);
            lectura_control();
       }
    }

     if(aux == 1) {

        sentado_levanta();
        aux = 0;
        delay(300);
    }

//--------------------------se pulsa circulo  ---------------------------------

    while(variable_control == 8) { //fue pulsado circulo

        if(aux == 0)
            saluda();

        aux = 1;
        delay(10);
        lectura_control();

        while(variable_control == 8) { //fue pulsado circulo
            delay(10);
            mueve_pata_frente();
            lectura_control();
       }
    }

    if(aux == 1) {
        saluda_levanta();
        aux=0;
        delay(300);
    }

//--------------------------se pulsa X   ---------------------------------

    while(variable_control == 9) { //fue pulsado X

        if(aux == 0)
            alaba();

        aux=1;
        delay(10);
        lectura_control();

        while(variable_control == 9) { //fue pulsado x
            delay(10);
            lectura_control();
        }
    }

    if(aux == 1) {
        alaba_levanta();
        aux = 0;
        delay(300);
    }

//--------------------------se pulsa Cuadrado   ---------------------------------

    while(variable_control==10) { //fue pulsado cuadrado

        if(aux == 0)
        angelito_cae();
        aux = 1;
        delay(10);
        lectura_control();

        while(variable_control==10) { //fue pulsado cuadrado
            delay(10);
            angelito_saluda();
            lectura_control();
        }
    }

    if(aux == 1) {
        aux = 0;
        delay(300);
    }

//-------------------comandos de movimientos normales--------------------
    if(variable_control == 11) { //fue pulsado arriba
        movimiento_izq=-300;
        movimiento_der=-300;
        Camina_frente();
    }
    if(variable_control == 12) { //fue pulsado abajo
        camina_atras();
    }
    if(variable_control == 13) { //fue pulsado izquierda
        Gira_der();
    }
    if(variable_control == 14) { //fue pulsado derecha
        Gira_izq();
    }

//----------------comando aumento y disminucion de velocidad--------------------------

    if(variable_control == 23) { //si no llegan comandos de la PS2 hago nada
        Time = Time + 20;
        if(Time > 240)
            Time = 240;
    }

    if(variable_control == 24) { //si no llegan comandos de la PS2 hago nada
        Time = Time - 20;
        if(Time < 10)
            Time = 10;
    }
}

(click para ampliar)

(click para ampliar)

(click para ampliar)

La memoria, en sentido general, es una función del cerebro y a la misma vez un proceso psíquico que nos permite codificar, almacenar y posteriormente recuperar la información o las vivencias. La memoria surge como resultado de las conexiones sinápticas entre neuronas que, a lo largo del tiempo, crean una serie de redes neuronales de forma que los recuerdos se mantienen relativamente estables en el tiempo.

La memoria es el único paraíso del que no podemos ser expulsados.
(Jean Paul)

En relación con el alcance temporal de la memoria ésta se clasifica en: memoria a corto plazo, a mediano plazo y a largo plazo.

La memoria a corto plazo tiene una capacidad muy limitada, tanto en volumen de almacenamiento como en tiempo de permanencia. La información se puede mantener en la memoria a corto plazo mediante la repetición.

Por ejemplo, cuando nos dicen un número de teléfono y lo vamos repitiendo hasta encontrar un papel donde apuntarlo.

Si uno presta atención a esta información y la elabora (analiza, comprende, relaciona con otras ideas) puede pasar de la memoria a corto plazo a la memoria a largo plazo.

La memoria a largo plazo es prácticamente ilimitada tanto en capacidad como en duración.

La memoria a corto plazo, también denominada “memoria operativa”, es un sistema a partir del cual la persona maneja la información que se obtiene de una interacción directa con el ambiente que le rodea. Generalmente esta información se encuentra limitada a 7 elementos, con una variación de más o menos 2 ítems y puede mantenerse durante una media que oscila entre los 15 y los 30 segundos. No obstante, la memoria a corto plazo se verá más o menos limitada en relación con las capacidades de cada persona y el entrenamiento que ha realizado a lo largo de la vida.

Generalmente la memoria a corto plazo funciona a partir de tres principios muy sencillos: el efecto de primacía, el efecto de recencia y la significatividad.

El efecto de primacía hace referencia al hecho de que las personas recuerdan mejor las cosas que suceden inicialmente (ya sea los primeros ítems de una lista o las primeras palabras de una conversación). El efecto de recencia, al contrario, se refiere a nuestra excelente memoria para los hechos o datos que se presentan al final de una lista o una situación. Así, la tendencia de la memoria a corto plazo será la de transferir a la memoria a largo plazo los datos primeros o últimos; obviando buena parte de los hechos o datos intermedios. No obstante, si las informaciones intermedias tienen un gran significado emocional para las personas, entonces éstas adquirirán la primacía absoluta.

La memoria a corto plazo cumple varias funciones:

  • Retención de la información por un periodo corto de tiempo.
  • Apoyo al aprendizaje del nuevo conocimiento.
  • Comprensión del ambiente.
  • Facilitación del proceso de solución de problemas.

En esta ocasión crearemos un juego con Arduino para entrenar y mejorar el rendimiento de nuestra memoria a corto plazo.

El circuito esquemático de este juego de entrenamiento de la memoria se observa en la siguiente imagen:

Lista de Componentes
5 Resistencias 10KΩ 0.25W
4 Resistencias 390Ω 0.25W
1 LED 5mm Azul [Alto brillo]
1 LED 5mm Amarillo [Alto brillo]
1 LED 5mm Verde [Alto brillo]
1 LED 5mm Rojo [Alto brillo]
4 Pulsadores N.A. o Push-Button N.A.
1 Transistor NPN 2SC1815
1 Buzzer Pasivo 5V
1 Placa Arduino Nanino

/*
  Memory Game with Arduino
  Based on a project by Jeremy Wilson
  Modified by Rui Santos
  Visit: http://randomnerdtutorials.com
*/

#define BLUE_BUTTON     2
#define YELLOW_BUTTON   3
#define GREEN_BUTTON    4
#define RED_BUTTON      5
#define BLUE_LED        7
#define YELLOW_LED      8
#define GREEN_LED       9
#define RED_LED         10
#define BUZZER          12

// Constants
const int tones[] = {1915, 1700, 1519, 1432, 2700}; // tones when you press the LED's - the last one is when you fail.

// Variables
int buttonState[] = {0, 0, 0, 0};         // current state of the button
int lastButtonState[] = {0, 0, 0, 0};     // previous state of the button
int buttonPushCounter[] = {0, 0, 0, 0};
int game_on = 0;
int wait = 0;
int currentlevel = 1; // This is the level (also the number of button presses to pass to next level)
int rando = 0; //initialize random integer for loopgame_on. Will be from 1-4 later.
int butwait = 500; //amount of time to wait for next button input (ghetto de-bounce)
int ledtime = 500; //amount of time each LED flashes for when button is pressed
int n_levels = 10; //number of levels until the game is won
int pinandtone = 0; //This integer is used when the sequence is displayed
int right = 0; //This variable must be 1 in order to go to the next level
int speedfactor = 5; //This is the final speed of the lights and sounds for the last level. This increases as more games are won
int leddelay = 200; //Initializing time for LED. This will decrease as the level increases

long rand_num = 0; //initialize long variable for random number from 0-100.

void playTone(int tone, int duration) {
    for(long i = 0; i < duration * 1000L; i += tone * 2) {
        digitalWrite(BUZZER, HIGH);
        delayMicroseconds(tone);
        digitalWrite(BUZZER, LOW);
        delayMicroseconds(tone);
    }
}

void setup() {
    // initialize inputs:
    randomSeed(analogRead(0));
    pinMode(BLUE_BUTTON, INPUT);
    pinMode(YELLOW_BUTTON, INPUT);
    pinMode(GREEN_BUTTON, INPUT);
    pinMode(RED_BUTTON, INPUT);

    // initialize outputs:
    pinMode(BLUE_LED, OUTPUT);
    pinMode(YELLOW_LED, OUTPUT);
    pinMode(GREEN_LED, OUTPUT);
    pinMode(RED_LED, OUTPUT);
    pinMode(BUZZER, OUTPUT);
}

void loop() {

    int n_array[n_levels];
    int u_array[n_levels];
    int i;

    //clears arrays both "n_array" and "u_array" and starts a new game
    if(game_on == 0) {
        for(i = 0; i < n_levels; i = i + 1) {
            n_array[i] = 0;
            u_array[i] = 0;
            rand_num = random(1, 200);

            if(rand_num <= 50)
                rando = 0;
            else if(rand_num > 50 && rand_num <= 100)
                rando = 1;
            else if(rand_num > 100 && rand_num <= 150)
                rando = 2;
            else if(rand_num <= 200)
                rando = 3;
            //saves a random number in our n_array
            n_array[i] = rando;
        }
        game_on = 1;
    }

    //shows the user the current sequence
    if(wait == 0) {
        delay(200);
        i = 0;

        for(i = 0; i < currentlevel; i = i + 1) {
            leddelay = ledtime/(1+(speedfactor/n_levels)*(currentlevel - 1));
            pinandtone = n_array[i];
            digitalWrite(pinandtone+7, HIGH);
            playTone(tones[pinandtone], leddelay);
            digitalWrite(pinandtone+7, LOW);
            delay(100/speedfactor);
        }
        wait = 1;
    }

    i = 0;
    int buttonchange = 0;
    int j = 0; // This is the current position in the sequence

    while(j < currentlevel) {
        while(buttonchange == 0) {
            for(i = 0; i < 4; i = i + 1) {
            buttonState[i] = digitalRead(i + 2);
            buttonchange = buttonchange + buttonState[i];
            }
        }
        for(i = 0; i < 4; i = i + 1) {
            if(buttonState[i] == HIGH) {
                digitalWrite(i+7, HIGH);
                playTone(tones[i], ledtime);
                digitalWrite(i+7, LOW);
                wait = 0;
                u_array[j] = i;
                buttonState[i] = LOW;
                buttonchange = 0;
            }
        }
        if(u_array[j] == n_array[j]) {
            j++;
            right = 1;
        }
        else {
            right = 0;
            i = 4;
            j = currentlevel;
            wait = 0;
        }
    }

    if(right == 0) {
        delay(300);
        i = 0;
        game_on = 0;
        currentlevel = 1;
        for(i = 0; i < 4; i = i + 1) {
            digitalWrite(i + 7, HIGH);
        }
        playTone(tones[4], ledtime);
        for(i = 0; i < 4; i = i + 1) {
            digitalWrite(i + 7, LOW);
        }
        delay(200);
        for(i = 0; i < 4; i = i + 1) {
            digitalWrite(i+7, HIGH);
        }
        playTone(tones[4], ledtime);
        for(i = 0; i < 4; i = i + 1) {
            digitalWrite(i + 7, LOW);
        }

        delay(500);
        game_on = 0;
    }

    //if you insert the right sequence it levels up
    if(right == 1) {
        currentlevel++;
        wait = 0;
    }

    //if you finish the game
    if(currentlevel == n_levels) {
        delay(500);
        // The following is the victory sound:

        int notes[] = {2, 2, 2, 2, 0, 1, 2, 1, 2};
        int note = 0;
        int tempo[] = {200, 200, 200, 400, 400, 400, 200, 200, 600};
        int breaks[] = {100, 100, 100, 200, 200, 200, 300, 100, 200};

        for(i = 0; i < 9; i = i + 1) {
            note = notes[i];
            digitalWrite(note + 7, HIGH);
            playTone(tones[note], tempo[i]);
            digitalWrite(note + 7, LOW);
            delay(breaks[i]);
        }

        //sets game_on to 0, so it restarts a new game
        game_on = 0;
        currentlevel = 1;
        n_levels = n_levels + 2;
        speedfactor = speedfactor + 1;
    }
}

(click para ampliar)

(click para ampliar)

  • Agradecimientos: A mi prometida por haber grabado el siguiente video demo, por su tolerancia y comprensión. Sin ella nada de esto sería posible. TE AMO POR Y PARA SIEMPRE M.L.V!!! ❤ ❤ ❤ ❤